Mixed script pipeline

This pipeline shows how to use different scripting languages in a single Nextflow pipeline. The first process uses a Perl script to generate random number pairs, and the second process uses a Python script to calculate the average of each pair.

// Default parameter input
params.range = 100

// Perl process
process perlTask {
    output:
    stdout

    script:
    """
    #!/usr/bin/env perl
    use strict;
    use warnings;

    my \$count;
    my \$range = ${params.range};
    for (\$count = 0; \$count < 10; \$count++) {
        print rand(\$range) . ', ' . rand(\$range) . "\\n";
    }
    """
}

// Python process
process pyTask {
    input:
    stdin

    output:
    stdout

    script:
    """
    #!/usr/bin/env python
    import sys

    x = 0
    y = 0
    lines = 0
    for line in sys.stdin:
        items = line.strip().split(",")
        x += float(items[0])
        y += float(items[1])
        lines += 1

    print("avg: %s - %s" % ( x/lines, y/lines ))
    """
}

// Workflow block
workflow {
    perlTask | pyTask | view
}